명령형 언어 – If/Then/Else

이 섹션은 에이다(Ada)의 if 문(statement)을 설명하고, 정수 입출력(Integer I/O), 데이터 선언, 서브프로그램 파라미터(매개변수) 모드 등 여러 다른 기본적인 언어 기능들을 소개합니다.

에이다의 if 문의 형태와 기능은 꽤 예상대로입니다:

with Ada.Text_IO;         use Ada.Text_IO;
with Ada.Integer_Text_IO; use Ada.Integer_Text_IO;

procedure Check_Positive is
   N : Integer;
begin
   --  문자열 출력하기
   Put ("Enter an integer value: ");

   --  정수 값 입력받기
   Get (N);

   if N > 0 then
      --  정수 출력하기
      Put (N);
      Put_Line (" is a positive number");
   end if;
end Check_Positive;

if 문은 최소한 예약어 if, 불리언(Boolean) 값이어야 하는 조건식, 예약어 then, 그리고 하나 이상의 문장들(then 부분)로 구성되는데, 이 부분은 조건식이 True로 평가될 경우 실행됩니다. 그리고 마지막으로 종료를 나타내는 end if가 옵니다.

이 예제는 정수 변수 N을 선언하고, 사용자에게 정수 입력을 요청한 다음, 입력된 값이 양수인지 확인합니다. 만약 양수이면, 해당 정수 값과 그 뒤에 " is a positive number" 문자열을 출력합니다. 값이 양수가 아니라면, 이 프로시저는 아무런 출력도 하지 않습니다.

Integer 타입은 미리 정의된 부호 있는 타입이며, 그 범위는 컴퓨터 아키텍처에 따라 다릅니다. 일반적인 최신 프로세서에서 Integer는 32비트 부호 있는 정수입니다.

이 예제는 정수 입출력의 몇 가지 기본적인 기능을 보여줍니다. 관련된 서브프로그램들은 미리 정의된 Ada.Integer_Text_IO 패키지에 포함되어 있으며, 키보드로부터 숫자를 읽어 들이는 Get 프로시저와 정수 값을 출력하는 Put 프로시저 등이 있습니다.

다음은 else 부분을 포함하는 if 문을 보여주는 약간 변형된 예제입니다:

with Ada.Text_IO;         use Ada.Text_IO;
with Ada.Integer_Text_IO; use Ada.Integer_Text_IO;

procedure Check_Positive is
   N : Integer;
begin
   --  문자열 출력하기
   Put ("Enter an integer value: ");

   --  정수 값 입력받기
   Get (N);

   --  정수 출력하기
   Put (N);

   if N > 0 then
      Put_Line (" is a positive number");
   else
      Put_Line (" is not a positive number");
   end if;
end Check_Positive;

이 예제에서는 입력 값이 양수가 아닐 경우, 프로그램은 해당 값과 그 뒤에 " is not a positive number" 문자열을 출력합니다.

마지막 변형 예제는 elsif 부분을 포함하는 if 문을 보여줍니다:

with Ada.Text_IO;         use Ada.Text_IO;
with Ada.Integer_Text_IO; use Ada.Integer_Text_IO;

procedure Check_Direction is
   N : Integer;
begin
   Put ("Enter an integer value: ");
   Get (N);
   Put (N);

   if N = 0 or N = 360 then
      Put_Line (" is due north");
   elsif N in 1 .. 89 then
      Put_Line (" is in the northeast quadrant");
   elsif N = 90 then
      Put_Line (" is due east");
   elsif N in 91 .. 179 then
      Put_Line (" is in the southeast quadrant");
   elsif N = 180 then
      Put_Line (" is due south");
   elsif N in 181 .. 269 then
      Put_Line (" is in the southwest quadrant");
   elsif N = 270 then
      Put_Line (" is due west");
   elsif N in 271 .. 359 then
      Put_Line (" is in the northwest quadrant");
   else
      Put_Line (" is not in the range 0..360");
   end if;
end Check_Direction;

이 예제는 사용자에게 0과 360 사이(경계값 포함)의 정수를 입력하도록 기대하며, 해당 값이 어느 사분면 또는 축에 해당하는지를 출력합니다. 에이다(Ada)의 in 연산자는 스칼라 값이 지정된 범위 내에 있는지 검사하고 불리언(Boolean) 결과를 반환합니다. 프로그램의 동작은 자명할 것입니다. 나중에 case 문을 통해 동일한 효과를 달성하는 대안적이고 더 효율적인 스타일을 살펴볼 것입니다.

에이다의 elsif 키워드는 중첩된 else .. if 블록을 대신 사용하는 C나 C++와 다릅니다. 또 다른 차이점은 에이다에 end if가 존재한다는 것인데, 이는 “댕글링 else(dangling else)”로 알려진 문제를 피하게 해줍니다.