명령형 언어 – Case 문 (Case statement)

Ada의 case 문은 C와 C++의 switch 문과 유사하지만, 몇 가지 중요한 차이점이 있습니다.

다음은 이전에 if 문으로 보여주었던 프로그램의 변형 예제입니다:

with Ada.Text_IO;         use Ada.Text_IO;
with Ada.Integer_Text_IO; use Ada.Integer_Text_IO;

procedure Check_Direction is
   N : Integer;
begin
   loop
      Put ("Enter an integer value: ");
      Get (N);
      Put (N);

      case N is
         when 0 | 360 =>
            Put_Line
              (" is due north");
         when 1 .. 89 =>
            Put_Line
              (" is in the northeast quadrant");
         when 90 =>
            Put_Line
              (" is due east");
         when 91 .. 179 =>
            Put_Line
              (" is in the southeast quadrant");
         when 180 =>
            Put_Line
              (" is due south");
         when 181 .. 269 =>
            Put_Line
              (" is in the southwest quadrant");
         when 270 =>
            Put_Line
              (" is due west");
         when 271 .. 359 =>
            Put_Line
              (" is in the northwest quadrant");
         when others =>
            Put_Line
              (" Au revoir");
            exit;
      end case;
   end loop;
end Check_Direction;

이 프로그램은 사용자에게 반복적으로 정수 값을 입력하라는 프롬프트(prompt)를 표시하고, 그런 다음 만약 그 값이 0 .. 360 범위 내에 있으면 관련된 사분면(quadrant) 또는 축(axis)을 표시합니다. 만약 값이 이 범위 밖의 정수이면, 작별 메시지를 출력한 후 루프(및 프로그램)가 종료됩니다.

case 문의 효과는 이전 예제의 if 문과 유사하지만, 여러 번의 범위 검사를 포함하지 않기 때문에 case 문이 더 효율적일 수 있습니다.

Ada case 문의 주목할 만한 점들:

• case 표현식(여기서는 변수 N)은 반드시 이산 타입(discrete type), 즉 정수 타입(integer type) 또는 열거 타입(enumeration type)이어야 합니다. 이산 타입에 대해서는 나중에 이산 타입 섹션에서 더 자세히 다룰 것입니다.
• case 표현식에 대한 모든 가능한 값은 case 문의 유일한 분기(branch)에 의해 처리(cover)되어야 합니다. 이는 컴파일 시점에 검사될 것입니다.
• 분기(branch)는 0과 같은 단일 값을 명시할 수 있고, 1 .. 89와 같은 값의 범위를 명시할 수도 있으며, 또는 이 둘의 어떤 조합(|로 구분됨)도 명시할 수 있습니다.
• 특별한 경우로, 선택적인 마지막 분기(branch)는 others를 명시할 수 있는데, 이는 이전 분기들에서 포함되지 않은 모든 값을 처리(cover)합니다.
• 실행은 case 표현식의 평가와 그런 다음 그 값을 처리(cover)하는 유일한 분기(branch) 내의 문장 시퀀스(statement sequence)로 제어가 이전되는 것으로 구성됩니다.
• 선택된 분기 내의 문장 실행이 완료되면, 제어는 end case 이후부터 재개됩니다. C와 달리, 실행이 다음 분기로 넘어가지(fall through) 않습니다. 따라서 Ada는 break 문이 필요하지 않으며 (가지고 있지도 않습니다).